Bài 2 - Led 7 Thanh
Chào các bạn! Hôm nay chip hướng dẫn các bạn lập trình điều khiển led 7 thanh ( hay led 7 đoạn cũng thế)
Trước hết đi tìm hiểu phân loại, cấu tạo led 7 thanh.
- Phân loại led 7 thanh:
Led 7 thanh trên thị trường có nhiều loại to nhỏ về kích thước và được tích hợp 2 con,3 con đến 4 con led ghép lại.
- Có 2 loại led 7 thanh trên thị trường là Led 7 thanh ANode chung và Led 7 thanh Cathode chung
+ Led 7 thanh ANode chung được dùng nhiều hơn vì độ sáng vượt trội hơn ( mắc theo kiểu Anode chung của led đơn dùng điện áp ngoài, không phải điện áp từ chân VĐK). Sơ đồ bên dưới Chip vẽ sơ đồ cấu tạo, bảng giải mã led và mô phỏng Protues cho các bạn xem sẽ dễ hiểu hơn.
+ Led 7 thanh cathode chung:
Chương trình mô phỏng đếm led 7 thanh Anode chung:
+ Phương pháp nối Port trực tiếp:
Chương trình mẫu 00 - 99:
ORG 0000H
MAIN:
MOV R0,#00
LAP:
CALL CTHT
INC R0
CJNE R0,#100,LAP
JMP MAIN
CTHT:
MOV R7,#1
QUAY:
MOV A,R0
MOV B,#10
DIV AB
MOV DPTR,#MALED
MOVC A,@A+DPTR
MOV P2,A
CALL DELAY
MOV A,B
MOVC A,@A+DPTR
MOV P3,A
CALL DELAY
DJNZ R7,QUAY
RET
MALED: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H
DELAY:
MOV R4,#150
LOOP:
MOV R5,#200
LOOP1:
DJNZ R5,LOOP1
DJNZ R4,LOOP
RET
END
( File code + Mô phỏng ) Pass: Chipkool
Khi nhấn nút "Tải Về Máy", bạn sẽ vào trang quảng cáo, vui lòng chờ 5 giây. Nút 
hiện ra ở góc phải phía trên, nhấn vào để đến trang download
hiện ra ở góc phải phía trên, nhấn vào để đến trang download
+ Phương pháp quét:
CHƯƠNG TRÌNH :
ORG 00H
MAIN:
MOV R0,#0 ; GIA TRI BAN DAU
LAP:
INC R0 ; TANG BIEN DEM
CALL HT
CJNE R0,#100,LAP ; GIOI HAN CUA GIA TRI
JMP MAIN
HT: ; CHUONG TRINH HIEN THI LED 7 DOAN
MOV DPTR,#MALED ; GAN MA CHO THANH GHI CONTROL
MOV R7,#50 ; SO LAN QUET
QUET:
MOV A,R0
MOV B,#10
DIV AB ; CHIA LAY RA PHAN CHUC
MOVC A,@A+DPTR ; LAY MA LED HANG CHUC
MOV P2,A ; XUAT DU LIEU RA PORT
SETB P3.0 ; CHO PHEP HIEN THI
CALL DELAY
CLR P3.0
MOV A,B ; LAY GIA TRI HANG DON VI
MOVC A,@A+DPTR ;LAY MA LED HANG DON VI
MOV P2,A ; XUAT DU LIEU
SETB P3.1 ; CHO PHEP HIEN THI RA LED
CALL DELAY
CLR P3.1
DJNZ R7,QUET
RET
DELAY: ;THOI GIAN TRE
MOV R1,#150
LAPA:
MOV R2,#20
LAPB:
DJNZ R2,LAPB
DJNZ R1,LAPA
RET
ORG 500 ; MA LED 7 DOAN
MALED:
DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H
END
( File code + Mô phỏng ) Pass: ChipkoolKhi nhấn nút "Tải Về Máy", bạn sẽ vào trang quảng cáo, vui lòng chờ 5 giây. Nút
hiện ra ở góc phải phía trên, nhấn vào để đến trang download+ Phương pháp Giải mã dùng IC 74HC47:
Chương trình:
ORG 00H
MAIN:
CALL CTA
JMP MAIN
CTA:
MOV R0,#0
MOV A,R0
NEXT1:
ANL A,#0F0H ; XOA 4 BIT THAP
;NEU XOA 4 BIT CAO THI BO LENH SWAP
SWAP A ; DAO 4 BIT CAO CHO 4 BIT THAP
MOV P2,A
CALL DELAY
MOV A,R0
ADD A,#1 ; TANG GIA TRI DEM
DA A ; HIEU CHINH
MOV R0,A
CJNE R0,#10,NEXT1
RET
DELAY:
MOV R4,#250
STOP:
MOV R5,#200
DJNZ R5,$
DJNZ R4,STOP
RET
END
( File code + Mô phỏng ) Pass: ChipkoolKhi nhấn nút "Tải Về Máy", bạn sẽ vào trang quảng cáo, vui lòng chờ 5 giây. Nút
hiện ra ở góc phải phía trên, nhấn vào để đến trang download
+ Phương pháp chốt dùng IC 74HC373 - 374:
Chương trình:
ORG 00H
MAIN:
CALL CTA
JMP MAIN
CTA:
MOV P2,#00H ; TAT CAC PORT DU LIEU
MOV P3,#00H
MOV R1,#0 ; GIA TRI BAN DAU CUA BIEN DEM
MOV DPTR,#MALED ; DUA MA LED 7 DOAN VAO THANH GHI CONTROL
NEXT:
CALL HT ; CHUONG TRINH HIEN THI RA LED 7 DOAN
INC R1 ; TANG GIA TRI BIEN DEM
CJNE R1,#100,NEXT ; KIEM TRA GIA TRI BIEN DEM =100 THI KET THUC
RET
HT: ; CHUONG TRINH HIEN THI RA LED 7 DOAN
MOV A,R1
MOV B,#10
DIV AB ; LAY GIA TRI HANG CHUC
MOVC A,@A+DPTR; LAY MA LED
MOV P2,A ;XUAT DU LIEU RA PORT VA HIEN THI TREN LED 7 DOAN
SETB P3.0
CLR P3.0
MOV A,B ; LAY GIA TRI HANG DON VI
MOVC A,@A+DPTR ; LAY MA LED HANG DON VI
MOV P2,A ; XUAT VA HIEN THI TREN LED 7 DOAN
SETB P3.1
CLR P3.1
CALL DELAY
RET
DELAY: ; THOI GIAN TRE
MOV R2,#250
STOP:
MOV R3,#250
STOP2:
DJNZ R3,STOP2
DJNZ R2,STOP
RET
MALED: ; MA LED
DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H
END
( File code + Mô phỏng ) Pass: ChipkoolKhi nhấn nút "Tải Về Máy", bạn sẽ vào trang quảng cáo, vui lòng chờ 5 giây. Nút
hiện ra ở góc phải phía trên, nhấn vào để đến trang download
+ Phương pháp dùng 74HC595:
Chương trình:
ORG 00H ; BAT DAU CHUONG TRINH
MAIN:
CALL CTA
JMP MAIN
CTA:
MOV R0,#0 ; GIA TRI BAN DAU CUA BIEN DEM
NEXT1:
CALL HT ; CHUONG TRINH HIEN THI RA LED 7 DOAN
INC R0
CJNE R0,#100,NEXT1
RET
HT:
MOV R1,#10 ; GIA TRI CUA VONG LAP
QUET:
MOV DPTR,#MALED ; GAN MA LED VAO THANH GHI CONTROL
MOV A,R0
MOV B,#10
DIV AB
MOV R2,A ; CAT GIA TRI HANG CHUC VAO THANH GHI
MOV A,B ; LAY GIA TRI HANG DON VI
MOVC A,@A+DPTR ; LAY MA LED 7 DOAN HANG DON VI
CALL HT1 ; GOI CHUONG TRINH DUA GIA TRI VAO 595
SETB P2.2 ; CHO PHEP 595 XUAT DU LIEU
CLR P2.2
SETB P3.7 ; HIEN THI RA LED
CALL DELAY
CLR P3.7
MOV A,R2 ; LAY GIA TRI HANG CHUC
MOVC A,@A+DPTR ; LAY MA LED 7 DOAN HANG CHUC
CALL HT1 ; GOI CHUONG TRINH DUA GIA TRI VAO 595
SETB P2.2 ; CHO PHEP 595 XUAT DU LIEU
CLR P2.2
SETB P3.6 ; HIEN THI RA LED
CALL DELAY
CLR P3.6
DJNZ R1,QUET
RET
HT1: ; CHUONG TRINH XU LY DUA DU LIEU VAO 595
MOV R3,#8 ; SO LAN DAY DU LIEU VAO 595
NEXT2:
RLC A ; QUAY CO NHO DU LIEU CAN DUA VAO 595
JNC GT0 ; KIEM TRA CO C =0 THI NHAY DEN NHAN GT0
JC GT1 ; CO C=1 THI NHAY DEN NHAN GT1
NEXT3:
DJNZ R3,NEXT2
RET
GT1: ; CHUONG TRINH DUA GIA TRI 1 VAO 595
SETB P2.1 ; DUA CHAN DS LEN MUC CAO
SETB P2.0 ; CHO PHEP DUA DU LIEU VAO 595
CLR P2.0
JMP NEXT3 ; QUAY LAI CUONG TRINH DUA TIEP DU LIEU VAO
GT0: ; CHUONG TRINH DUA GIA TRI 0 VAO 595
CLR P2.1 ;XOA DUA LIEU CHAN DS
SETB P2.0 ; CHO PHEP DUA DU LIEU VAO 595
CLR P2.0
JMP NEXT3 ; QUAY LAI CHUONG TRINH DUA TIEP DU LIEU VAO
DELAY: ; THOI GIAN TRE
MOV R4,#250
STOP:
MOV R5,#50
DJNZ R5,$
DJNZ R4,STOP
RET
MALED: ; MA LED 7 DOAN
DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H
END
link:http://adf.ly/OhaYu
http://adf.ly/Ohawj http://adf.ly/OhcEb http://adf.ly/OhcHS
Chúc các bạn thành công!
Blog Điện Tử | Tin học - Chia sẻ khiến thức kế nối đam mê
0 nhận xét:
Đăng nhận xét